Jenkins流水线任务配置(企业微信机器人通知)

字数统计: 2.5k字   |   阅读时长≈ 12分

前言

       Jenkins的Pipeline相比Freestyle构建的任务有着整体流程可视化，执行阶段明确，定位问题方便快速，配置简单也便于维护等诸多优点。

一、创建Jenkins流水线任务

1.新建任务

新建流水线任务.png

2.配置任务-清除构建策略

配置任务0.png
保持构建天数和保持构建最大个数，配成90和10基本够用
配置任务1.png

3.配置任务-流水线配置项

配置任务2.png

4.配置任务-构建触发器（手动触发可不配置）

配置任务3.png

二、编写流水线脚本

Pipline script SCM方式配置的流水线脚本是直接将脚本以Jenkinsfile命名放在gitlab项目根目录下。
流水线脚本支持Groovy语法，具体的写法可以参考Jenkins官方文档

1.前端Jenkinsfile配置示例
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
#!/usr/bin/env groovy

/**
 * Jenkins 前端流水线脚本配置复用说明
 *
 * 除了以下参数，构建脚本和部署脚本也需要根据项目实际情况自定义配置
 * @JOB_ADDRESS 项目环境地址
 * @SSH_ADDRESS 目标服务器地址
 * @QY_ADDRESS 企业微信机器人webhook  （需要在企业微信项目群添加机器人）
 * @credentialsId 目标服务器凭证id（需要在jenkins下配置添加全局凭证类型选择Username with password） 示例：aurora-ssh
 * @sourceFiles jenkins服务器上打好包的文件名
 **/

// 项目名称
JOB_NAME = ''
// 项目地址
JOB_ADDRESS = 'http://172.17.9.134:8000'
// 提交用户
GIT_USER = ''
// 提交分支
GIT_BRANCH = ''
// 提交消息
GIT_MESSAGE = ''
// 构建日志地址
BUILD_URL = ''
// 目标服务器地址
SSH_ADDRESS = '172.17.9.134'
// 企业微信机器人webhook
QY_ADDRESS = 'https://qyapi.weixin.qq.com/cgi-bin/webhook/send?key=xxxxxx'

// 发送通知消息
def noticeQy(result) {
    script {
        def noticeTitle = '前端Jenkins任务通知'
        def isSuccess = result == 'success'
        def status = isSuccess ? 'info' : 'warning'
        def statusText = isSuccess ? '成功' : '失败'
        def noticeContent = """<font color=\\"warning\\">${noticeTitle}</font>
            >状态:<font color=\\"${status}\\">${statusText}</font>
            >构建项目:**[${JOB_NAME}](${JOB_ADDRESS})**
            >代码分支:**${GIT_BRANCH}**
            >提交信息:**${GIT_MESSAGE}**
            >提交用户:**${GIT_USER}**
            >构建日志:[查看](${BUILD_URL})
        """

        echo "企业微信机器人webhook url: ${QY_ADDRESS}"
        echo "企业微信机器人webhook 内容: ${noticeContent}"

        echo "调用企业微信机器人消息通知webhook"
        sh """
            curl --connect-timeout 10 ${QY_ADDRESS} \
                -H 'Content-Type: application/json' \
                -d '{
                    "msgtype": "markdown",
                    "markdown": {
                        "content": "${noticeContent}"
                    }
                }'
       """
   }
}

pipeline {
    agent any

    stages {
        stage('Before Build') {
            steps {
                echo '定义变量'
                script {
                    JOB_NAME = env.JOB_BASE_NAME
                    GIT_USER = env.gitlabUserName ?: env.GIT_COMMITTER_NAME
                    GIT_BRANCH = env.gitlabBranch ?: env.GIT_BRANCH
                    BUILD_URL = "${env.BUILD_URL}console"
                    GIT_MESSAGE = sh(returnStdout: true, script: "git log --pretty=format:%s ${env.GIT_COMMIT} --no-merges -1")
                }
            }
        }
        stage('Build') {
            steps {
                sh label: '开始构建', 
                script: '''
                    echo '======【设置node环境变量】======'
                    export NODE_PATH=/opt/node16/bin
                    export PATH=/opt/node16/bin:$PATH
                    echo '======【检查打包环境】======'
                    node -v
                    npm -v
                    echo '======【安装依赖】======'
                    yarn --update-checksums && yarn
                    echo '======【开始打包】======'
                    yarn build
                    echo '======【查看目录】======'
                    ls -al $WORKSPACE/
                    echo '======【生成压缩包】======'
                    tar -zcvf front-dev.tar.gz platform
                    echo '======【检查压缩包】======'
                    ls -al $WORKSPACE/ | grep front-dev.tar.gz
                    echo '======【构建项目结束】======'
                '''
            }
        }
        stage('Deploy') {
            steps {
                echo '发布部署'
                withCredentials([usernamePassword(credentialsId: 'aurora-ssh', passwordVariable: 'SSH_PSW', usernameVariable: 'SSH_USR')]) {
                    sshPublisher(
                        publishers: [
                            sshPublisherDesc(
                                configName: SSH_ADDRESS,
                                sshCredentials: [
                                    username: SSH_USR,
                                    encryptedPassphrase: SSH_PSW
                                ],
                                transfers: [
                                    sshTransfer(
                                        remoteDirectory: '/home/appadmin/package/front',
                                        sourceFiles: 'front-dev.tar.gz',
                                        execCommand: '''
                                            echo '=========【检查部署包是否上传成功】========='
                                            ls -al /home/appadmin/package/front/ | grep front-dev.tar.gz
                                            echo '=========【备份platform目录】=========='
                                            cd /data/back/app/packages/cluster-web
                                            bak_platform=platform_`date +%F_%H-%M-%S`
                                            mv platform $bak_platform
                                            ls -1td platform_* | tail -n +3 | xargs rm -rf
                                            echo '=========【解压到platform】=========='
                                            tar -zxvf /home/appadmin/package/front/front-dev.tar.gz
                                            echo '=========【备份压缩包】============='
                                            cd /home/appadmin/package/front/
                                            bak_file=front-dev_`date +%F_%H-%M-%S`.tar.gz
                                            cp front-dev.tar.gz $bak_file
                                            ls -1td front-dev_* | tail -n +5 | xargs rm -rf
                                            echo '=========【部署结束】============='
                                        '''
                                    )
                                ],
                                verbose: true
                            )
                        ],
                        failOnError: true
                    )
                    // 构建产物归档
                    archiveArtifacts artifacts: 'front-dev.tar.gz', followSymlinks: false
                }
            }
        }
    }

    post {
        success {
            echo 'success'
            noticeQy('success')
        }
        failure {
            echo 'failure'
            noticeQy('failure')
        }
        always {
            echo '结束清除目录'
            deleteDir()
        }
    }
}
2.后端Jenkinsfile配置示例
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
#!/usr/bin/env groovy

/**
 * Jenkins 后端流水线脚本配置复用说明
 *
 * 除了以下参数，构建脚本和部署脚本也需要根据项目实际情况自定义配置
 * @JOB_ADDRESS 项目环境地址
 * @SSH_ADDRESS 目标服务器地址
 * @QY_ADDRESS 企业微信机器人webhook  （需要在企业微信项目群添加机器人）
 * @credentialsId 目标服务器凭证id（需要在jenkins下配置添加全局凭证类型选择Username with password） 示例：aurora-ssh
 * @sourceFiles jenkins服务器上打好包的文件名
 **/

// 项目名称
JOB_NAME = ''
// 项目地址
JOB_ADDRESS = 'http://172.17.9.134:8000'
// 提交用户
GIT_USER = ''
// 提交分支
GIT_BRANCH = ''
// 提交消息
GIT_MESSAGE = ''
// 构建日志地址
BUILD_URL = ''
// 目标服务器地址
SSH_ADDRESS = '172.17.9.134'
// 企业微信机器人webhook url
QY_ADDRESS = 'https://qyapi.weixin.qq.com/cgi-bin/webhook/send?key=xxxxxx'

// 发送通知消息
def noticeQy(result) {
    script {
        def noticeTitle = 'cm后端Jenkins任务通知'
        def isSuccess = result == 'success'
        def status = isSuccess ? 'info' : 'warning'
        def statusText = isSuccess ? '成功' : '失败'
        def statusTips = isSuccess ? '系统正在重启中，请稍后尝试' : '系统构建失败，请相关技术人员排查'
        def noticeContent = """<font color=\\"warning\\">${noticeTitle}</font>
            >状态:<font color=\\"${status}\\">${statusText}</font>
            >使用提醒:**${statusTips}**
            >构建项目:**[${JOB_NAME}](${JOB_ADDRESS})**
            >代码分支:**${GIT_BRANCH}**
            >提交信息:**${GIT_MESSAGE}**
            >提交用户:**${GIT_USER}**
            >构建日志:[查看](${BUILD_URL})
        """

        echo "企业微信机器人webhook url: ${QY_ADDRESS}"
        echo "企业微信机器人webhook 内容: ${noticeContent}"

        echo "调用企业微信机器人消息通知webhook"
        sh """
            curl --connect-timeout 10 ${QY_ADDRESS} \
                -H 'Content-Type: application/json' \
                -d '{
                    "msgtype": "markdown",
                    "markdown": {
                        "content": "${noticeContent}"
                    }
                }'
       """
   }
}

pipeline {
    agent any

    stages {
        stage('Before Build') {
            steps {
                echo '定义变量'
                script {
                    JOB_NAME = env.JOB_BASE_NAME
                    GIT_USER = env.gitlabUserName ?: env.GIT_COMMITTER_NAME
                    GIT_BRANCH = env.gitlabBranch ?: env.GIT_BRANCH
                    BUILD_URL = "${env.BUILD_URL}console"
                    GIT_MESSAGE = sh(returnStdout: true, script: "git log --pretty=format:%s ${env.GIT_COMMIT} --no-merges -1")
                }
            }
        }
        stage('Build') {
            steps {
                sh label: '开始构建',
                script: '''
                    echo '======【安装依赖打包】======'
                    cd $WORKSPACE/cscs/cmaster && mvn clean -U && mvn clean package -Dmaven.test.skip=true
                    echo '======【生成压缩包】======'
                    cd $WORKSPACE/cscs/cmaster/cmaster-std/target/ && tar -czf $WORKSPACE/cmaster-back-dev.tar.gz lib/cmaster-*.jar
                    echo '======【检查压缩包】======'
                    ls -al $WORKSPACE/ | grep cmaster-back-dev.tar.gz
                    echo '======【构建项目结束】======'
                '''
            }
        }
        stage('Deploy') {
            steps {
                echo '发布部署'
                withCredentials([usernamePassword(credentialsId: 'aurora-ssh', passwordVariable: 'SSH_PSW', usernameVariable: 'SSH_USR')]) {
                    sshPublisher(
                        publishers: [
                            sshPublisherDesc(
                                configName: SSH_ADDRESS,
                                sshCredentials: [
                                    username: SSH_USR,
                                    encryptedPassphrase: SSH_PSW
                                ],
                                transfers: [
                                    sshTransfer(
                                        remoteDirectory: '/home/appadmin/package/back',
                                        sourceFiles: 'cmaster-back-dev.tar.gz',
                                        execCommand: '''
                                            echo '=========【检查部署包是否上传成功】========='
                                            ls -al /home/appadmin/package/back/ | grep cmaster-back-dev.tar.gz
                                            echo '=========【部署开始】=========='
                                            cd /data/back/app/packages/cluster-app
                                            echo '=========【停止后端应用】=========='
                                            sh bin/cluster-app.sh stop
                                            echo '=========【备份lib目录】=========='
                                            bak_lib=lib_`date +%F_%H-%M-%S`
                                            cp -r lib $bak_lib
                                            ls -1td lib_* | tail -n +5 | xargs rm -rf
                                            echo '=========【替换cmaster相关的jar包】=========='
                                            rm -rf lib/cmaster-*.jar
                                            tar xvf /home/appadmin/package/back/cmaster-back-dev.tar.gz
                                            sh bin/cluster-app.sh start
                                            echo '=========【启动情况】=========='
                                            ps -ef|grep cluster-app|grep -v grep
                                            echo '=========【备份压缩包】============='
                                            cd /home/appadmin/package/back/
                                            bak_file=cmaster-back-dev_`date +%F_%H-%M-%S`.tar.gz
                                            cp cmaster-back-dev.tar.gz $bak_file
                                            ls -1td cmaster-back-dev_* | tail -n +5 | xargs rm -rf
                                            echo '=========【部署结束】============='
                                        '''
                                    )
                                ],
                                verbose: true
                            )
                        ],
                        failOnError: true
                    )
                    // 构建产物归档
                    archiveArtifacts artifacts: 'cmaster-back-dev.tar.gz', followSymlinks: false
                }
            }
        }
    }

    post {
        success {
            echo 'success'
            noticeQy('success')
        }
        failure {
            echo 'failure'
            noticeQy('failure')
        }
        always {
            echo '结束清除目录'
            deleteDir()
        }
    }
}

三、添加目标服务器凭证

注意作用域要包含前面配置的流水线任务，这里放到了App-Aurora目录下包含了前面配置的任务目录

1.选择目录

凭证0.png

2.添加凭证

凭证1.png

四、配置企业微信机器人

1.项目消息群中添加企业微信机器人

企业微信机器人添加.png

2.配置机器人消息模板（参考官方文档）

企业微信机器人配置说明0.png
企业微信机器人配置说明1.png

3.个人配置样例

curl命令：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
curl 'https://qyapi.weixin.qq.com/cgi-bin/webhook/send?key=**************************' \
  -H 'Content-Type: application/json' \
  -d '
 {
     "msgtype": "markdown",
     "markdown": {
         "content": "<font color=\"warning\">Jenkins任务通知</font>\n
          >状态:<font color=\"info\">成功</font>
          >构建项目:**[${JOB_BASE_NAME}](http://172.17.6.119:8300)**
          >代码分支:**${gitlabBranch}**
          >提交信息:**'"${GIT_MESSAGE}"'**
          >提交用户:**${gitlabUserName}**
          >构建日志:[查看](${BUILD_URL}console)"
     }
 }'

消息样式：
企业微信机器人通知.png

五、使用说明

方式1 手动点击Build Now开始任务

使用说明.png
上次成功的成品：
1.cluster-app-uat.tar.gz 归档命令保存的压缩包可直接下载
阶段视图：
1.Commits: 提交记录
2.Checkout SCM: 拉取项目代码切换到目标分支，加载流水线脚本Jenkinsfile
3.Before Build: 构建前获取gitlab提交信息 jenkins job信息 用于后续消息通知
4.Build: 根据拉取的目标代码在jenkins服务器上打包
5.Deploy在目标服务器操作打包文件部署启动应用
6.Post Action: 根据每个阶段执行结果，执行对应操作，执行成功或者失败都会发送消息以及清除构建目录
7.notice: 企业微信机器人消息通知

方式2 配置gitlab webhook触发任务 （配置方法可参考本人之前的文档）
赏

谢谢你请我吃糖果

微信

扫一扫，分享到微信

tag:

    缺失模块。
    1、请确保node版本大于6.2
    2、在博客根目录（注意不是yilia-plus根目录）执行以下命令：
    npm i hexo-generator-json-content --save

    3、在根目录_config.yml里添加配置：

      jsonContent:
    meta: false
    pages: false
    posts:
      title: true
      date: true
      path: true
      text: false
      raw: false
      content: false
      slug: false
      updated: false
      comments: false
      link: false
      permalink: false
      excerpt: false
      categories: false
      tags: true

主要涉及技术：
Java后端开发


联系QQ:875038467

很惭愧

只做了一点微小的工作
谢谢大家